远程桌面RDP优化脚本

Zack

脚本内容:
1.修改默认远程桌面的端口
2.默认显示帧数由30改为60
3.默认连接模式由tcp修改为udp

关于是否因该开启udp:
开启udp和60帧后能明显提升远程桌面显示流畅度.
但由于跨境线路或部分运营商会对udp进行QoS,可能会导致使用udp模式后不稳定.
如果开启udp后置顶连接栏上显示连接不稳定,这种情况下请不要开启udp模式.

使用中图形内容越丰富，占用的带宽越大(比如在远程桌面中看视频).
开启udp后相比tcp会增加部分带宽使用,所以存在tcp中正常而开启udp后卡顿的情况.
这种情况可以可以在任务管理器中的带宽使用中判断,查看当前上传峰值是否已经长时间超过服务器带宽上限.



流畅度测试和简单优化:
脚本运行完成后可以在远程桌面中访问www.testufo.com来测试流畅度.
一切正常的情况下,网页中第一行飞碟可以流畅飞过屏幕(可以参考本地浏览器效果).如果开启udp和60帧后测试不流畅,可以在mstsc.exe配置中做以下修改:
1.在显示选项卡中调低分辨率,并修改颜色为16位(分辨率和颜色影响使用带宽,正常使用16位色无影响).
2.在体验选项卡中取消桌面背景勾选(或取消全部勾选),并确保持久位图缓存勾选.

远程桌面里运行:保存为bat格式以管理员模式运行

@echo off 
color f0 
echo Create By cgmsv.com 
set /p s= RDP优化输入1,清理输入2: 
if "%s%"=="1" goto init 
if "%s%"=="2" goto clean 
if "%s%"=="" goto end 
goto end 
:init 
set /p c= 请输入新的端口: 
if "%c%"=="" goto end 
goto edit 
:edit 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v "PortNumber" /t REG_DWORD /d "%c%" /f 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber" /t REG_DWORD /d "%c%" /f 
echo 自动添加防火墙规则 
netsh advfirewall firewall add rule name="Remote Desktop TCP-In" dir=in action=allow protocol=TCP localport="%c%" 
netsh advfirewall firewall add rule name="Remote Desktop UDP-In" dir=in action=allow protocol=UDP localport="%c%" 
echo 设置显示帧数60 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations" /v "DWMFRAMEINTERVAL" /t REG_DWORD /d 15 /f 
echo 启用远程桌面服务 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f  
wmic RDTOGGLE WHERE ServerName='%COMPUTERNAME%' call SetAllowTSConnections 1
echo 即将重启远程桌面服务,连接会断开,之后请使用新端口%c%连接! 
echo 云服务器需要在后台防火墙添加新端口%c%的tcp,udp协议放行规则! 
echo 按任意键开始重启服务! 
pause 
net stop TermService /y 
net start TermService 
echo 优化完成,按任意键退出! 
pause 
exit 
:clean 
echo 还原远程桌面默认端口(3389端口) 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v "PortNumber" /t REG_DWORD /d 3389 /f 
reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber" /t REG_DWORD /d 3389 /f 
echo 删除远程桌面自定义防火墙规则 
netsh advfirewall firewall delete rule name="Remote Desktop TCP-In"  
netsh advfirewall firewall delete rule name="Remote Desktop UDP-In"  
echo 还原默认显示帧数30 
reg delete "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations" /v "DWMFRAMEINTERVAL" /f 
::echo 停用远程桌面服务 
::reg add "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 1 /f  
::wmic RDTOGGLE WHERE ServerName='%COMPUTERNAME%' call SetAllowTSConnections 0
::echo 关闭远程桌面服务 
::net stop TermService /y 
echo 清理完成,按任意键退出! 
pause 
exit 
:end 
echo 未作修改! 
pause
复制代码

本地运行:保存为bat格式以管理员模式运行

@echo off
color f0

echo Create By cgmsv.com
echo 跨境线路或运营商对udp进行QoS可能会导致udp模式不稳定.
echo 这种情况下请不要开启udp模式.
set /p s= 开启远程桌面服务udp模式输出1,关闭输入2:
if "%s%"=="1" goto init
if "%s%"=="2" goto clean
if "%s%"=="" goto end
goto end

:init
echo 启用远程桌面服务udp模式
reg add "HKEY_LOCAL_MACHINE\software\policies\microsoft\windows nt\Terminal Services\Client" /v fClientDisableUDP /t REG_DWORD /d 0 /f
echo udp模式已启用,按任意键退出!
pause
exit

:clean
echo 停用远程桌面服务udp模式
reg add "HKEY_LOCAL_MACHINE\software\policies\microsoft\windows nt\Terminal Services\Client" /v fClientDisableUDP /t REG_DWORD /d 1 /f
echo udp模式已停用,按任意键退出!
pause
exit

:end
echo 未作修改!
pause
复制代码

进一步优化:
1.在windows10+/windos server 2016+中使用H.264/AVC 444编码,修改后可以大幅降低带宽使用,并会增加CPU使用率.开启后可以流畅观看视频.只需要在远程主机设置.
按下win+R打开运行输入gpedit.msc来打开本地组策略编辑器.
选择计算机配置-管理模板-Windows组件-远程桌面服务-远程桌面会话主机-远程会话环境
为远程桌面连接设置 H.264/AVC 444 图形模式的优先级 修改为已启用

检查是否开启成功的方法:
按下win+R打开运行输入eventvwr.msc来打开事件查看器
选择事件查看器(本地)-应用程序和服务日志-Microsoft -Windows -RemoteDesktopServices-RdpCoreTS-Operational
点击筛选当前日志,在<所有事件 ID>栏中填写162,然后点确定.
如果中间窗口中有数据,打开显示:"客户端模式: 0，可用 AVC: 1，初始配置文件: 2048" 表示启用成功
如果没有数据,或者打开后显示"客户端模式: 0，可用 AVC: 1，初始配置文件: 2" 表示没有启用或启用失败.


2.在windows10+/windos server 2016+中使用GPU渲染并启用硬件编码,修改后画面变动大的场景可降低cpu使用率,但不影响带宽使用.需要远程主机与本地主机都有显卡与最新驱动,然后做出以下设置.
按下win+R打开运行输入gpedit.msc来打开本地组策略编辑器.
选择计算机配置-管理模板-Windows组件-远程桌面服务-远程桌面会话主机-远程会话环境
将硬件图形适配器应用于所有远程桌面服务会话 修改为为已启用
为远程桌面连接设置 H.264/AVC 444 图形模式的优先级 修改为已启用

检查是否开启成功的方法:
按下win+R打开运行输入eventvwr.msc来打开事件查看器
选择事件查看器(本地)-应用程序和服务日志-Microsoft -Windows -RemoteDesktopServices-RdpCoreTS-Operational
点击筛选当前日志,在<所有事件 ID>栏中填写170,然后点确定.
如果中间窗口中有数据,打开显示:"AVC硬件编码已启用:1" 表示启用成功
如果没有数据或者显示其他内容 表示没有启用或启用失败.

ming7778

不错不错，可以远程游戏了

baiydgvt1

不错不错，可以远程游戏了